求menu sma

張曉峰

如果我想整管理員選單要點整

重有點改d字顏色

tony987852

比個簡單既例子你...

public plugin_init(){
    register_plugin("Menu","1.0","storym88349")    //註冊腳本，常識就不多說了
    register_clcmd("say menu","ShowMenu",-1,"Show Menu")    //註冊命令，內容是說「menu」時執行ShowMenu
    register_menucmd(register_menuid("\y管理員選單:"), 1023, "MenuCMD" )    //註冊選單命令，menuid需與要連結的選單一樣才有用
}
public ShowMenu(id){    //這裡是輸入命令時的事件，在這裡顯示選單的內容
    new szMenuBody[256]    //以new選告szMenuBody為變數，以此作為載體來儲存選單內容
    new keys    //宣告按鍵
    new nLen = format( szMenuBody, 255, "\y管理員選單:^n" )    //選單標題、內容
    nLen += format( szMenuBody[nLen], 255-nLen, "^n\w1. 踢人" )
    nLen += format( szMenuBody[nLen], 255-nLen, "^n\w2. ban人" )
    nLen += format( szMenuBody[nLen], 255-nLen, "^n\w3. 停用插件選單" )
    nLen += format( szMenuBody[nLen], 255-nLen, "^n^n\w0. 退出" )
    keys = (1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9)    //設定按鍵，這不難懂吧？
    show_menu( id, keys, szMenuBody, -1 )    //顯示選單
}
public MenuCMD( id,key ){    //執行選單的命令，此處的id下方需要用到此變數才加
    switch( key ){    //switch在很多地方都用的到，ex:隨機選取
    case 0: client_cmd(id, "踢人選單果個命令")    //這裡的case0是w1的命令喔
    case 1: client_cmd(id, "ban人選單果個命令")
    case 2: client_cmd(id, "停用插件選單果個命令")
    }
}

顏色方面:
\w 係白色
\r 係紅色
\y 係黃色
\d 係灰色

張曉峰

SET權限點set

tony987852

要權限的話...

又是網上的

#include <amxmodx> // 任何AMXX需要的基本INC

public plugin_init() // 註冊插件
{       
        register_plugin("Menu","1.0","[B-Boy]L")
        register_clcmd( "say /menu","ExtraMenu")
}

public ExtraMenu(id)
{
        // 新增一個單位"menu" = 建立一個選單
        new menu = menu_create("\r選單名稱", "menu_handler");
        // 第一格為名稱
        // 白色 = \w
        // 黃色 = \y
        // 紅色 - \r
        // 灰色 - \d
        // 第二格為指令所去的Function

        // 新增Menu的選項
        menu_additem(menu, "\w Selection #1", "1", ADMIN_LEVEL_A);
        menu_additem(menu, "\w Selection #2", "2", 0);
        menu_additem(menu, "\w Selection #3", "3", 0);
        // menu為剛才新增的參數
        // \w Selection #1 為 第一項選項
        // 第三格 "1" 為 排在選單第幾項
        // ADMIN_LEVEL_A 是指執行的權限 , 詳細可閱USER.INI取得更多資訊
        // 如果填寫為 0 是指任何人適用

        // 設定此Menu 的離開位置和轉頁
        menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);


        // 顯示選單
        menu_display(id, menu, 0);

        // 自主性決定吧 如果使用 say 指令會顯示字在說話頻道 如果不想可加上這一行
        // 把 // Del去就行
        // return PLUGIN_HANDLED;
}

// 剛才設定此Function為按鍵的設凡
public menu_handler(id, menu, item)
{
        // 如果按離開會發生的事
        if( item == MENU_EXIT )
        {
                // 消除選單
                menu_destroy(menu);
                return PLUGIN_HANDLED;
        }

        // 新增一些為玩家設定的參數
        new data[6], iName[64];
        new access, callback;

        // 取得玩家的權限 及 其資料
        menu_item_getinfo(menu, item, access, data,5, iName, 63, callback);

        // 將你所按的鍵轉換成Number
        new key = str_to_num(data);

        // 列出Number所發生的事
        switch(key)
        {
                case 1:
                {
                        client_print(id, print_chat, "你按了按鍵一");
                        menu_destroy(menu);                // 消除選單
                        return PLUGIN_HANDLED;                // 離開插件
                }
                case 2:
                {
                        client_print(id, print_chat, "你按了按鍵2");
                        menu_destroy(menu);                // 消除選單
                        return PLUGIN_HANDLED;                // 離開插件
                }
                case 3:
                {
                        client_print(id, print_chat, "你按了按鍵3");
                        menu_destroy(menu);                // 消除選單
                        return PLUGIN_HANDLED;                // 離開插件
                }
        }

        // 消除選單
        menu_destroy(menu);
        //  離開插件
        return PLUGIN_HANDLED;
}

張曉峰

想set d字做
imessage
要點整

tony987852

即係client_print?

張曉峰

將呢個左去

tony987852

唔明....

張曉峰

我想將client_print
轉做imessage
識唔識

tony987852

imessage係咩黎...?